Dissipative chaotic flow

Trajectories approaching the attracting set

d=10;
r=28;
b=8/3;

(*initial conditions*)
icoord={{-49,-49,35},{49,-49,35},{49,49,35},{-49,49,35},{-49,-49,75},{49,-49,75},{49,49,75},{-49,49,77},{-49,-49,0},{49,-49,0},{49,49,0},{-49,49,0},{-49,-49,-35},{49,-49,-35},{49,49,-35},{-49,49,-37},{-49,-49,-65},{49,-49,-65},{49,49,-65},{-49,49,-67}};

dt =0.001;(*time step size*)
nmax=5000;(*time steps*)

dx=d (y[n]-x[n]);(*the system*)
dy=r x[n]-y[n]-x[n] z[n];
dz=x[n] y[n]-b z[n];

integ[ic__]:=RecurrenceTable[{
x[n+1]==x[n]+dx dt,
y[n+1]==y[n]+dy dt,
z[n+1]==z[n]+dz dt,
x[0]==ic[[1]],y[0]==ic[[2]],z[0]== ic[[3]]},
{x,y,z},{n,0,nmax}];

icp=Graphics3D[{Red,AbsolutePointSize[5],Point[icoord]}];
pp=ListPointPlot3D[integ/@icoord,PlotRange->All,PlotStyle-> {Black,PointSize[Small]},ImageSize->Large,LabelStyle->15,AxesLabel-> {x[t],y[t],z[t]}]/.Point->Line;
Show[pp,icp]

Trajectories approaching the attracting set 
(rewrite using the Eulers’s method, get 5 brownie points)

Clear[t,Tmax,x,y,z,tmax,d,r,b,ic]
Tmax=35;tail=4;xlimit=62;ylimit=65;zlimit=92;
d=10;
r=28;
b=8/3;

icoord={{-49,-49,35},{49,-49,35},{49,49,35},{-49,49,35},{-49,-49,75},{49,-49,75},{49,49,75},{-49,49,77},{-49,-49,0},{49,-49,0},{49,49,0},{-49,49,0}};
icoord1={{1.1,1,7}};
integ[ic__]:=NDSolve[{
x'[t]==d (y[t]-x[t]),
y'[t]==r x[t]-y[t]-x[t] z[t],
z'[t]==x[t] y[t]-b z[t],
x[0]==ic[[1]],y[0]==ic[[2]],z[0]==ic[[3]]},{x,y,z},{t,0,Tmax+tail},MaxSteps->Infinity]
ParametricPlot3D[Evaluate[{x[t],y[t],z[t]}/.integ/@icoord],{t,0,Tmax},AxesLabel-> {x[t],y[t],z[t]},PlotStyle->Thin,PlotRange->{{-xlimit,xlimit},{-ylimit,ylimit},{-20,zlimit}},BoxRatios->{1,1,1},PlotPoints->200,ImageSize->530,LabelStyle->20]

Animate[
Show[
ParametricPlot3D[Evaluate[{x[t],y[t],z[t]}/.integ/@icoord],{t,tmax-tail,tmax},AxesLabel-> {x[t],y[t],z[t]},PlotStyle->Thin,PlotRange->{{-xlimit,xlimit},{-ylimit,ylimit},{-20,zlimit}},BoxRatios->{1,1,1},PlotPoints->200,ImageSize->530,LabelStyle->20],
Graphics3D[{Blue,AbsolutePointSize[7],Point[icoord]}],
Graphics3D[{Red,AbsolutePointSize[5],Point[Dynamic[Flatten[Evaluate[{x[tmax],y[tmax],z[tmax]}/.integ/@icoord],1]]]}]
],
{tmax,tail,Tmax+tail},AnimationRunning->False,AnimationRate->0.6,SaveDefinitions->True]

Divergence of the flow

Clear[d,r,b,x,y,z,diffx,diffy,diffz]

diffx=d (y-x);
diffy=r x-y-x z;
diffz=x y-b z;
Print[Style["Divergence of the field, as a function of parameters",18,Blue]]
Div[{diffx,diffy,diffz},{x,y,z}]

d=10;
r=28;
b=8/3;
Print[Style["Divergence of the field",18,Blue]]
Div[{diffx,diffy,diffz},{x,y,z}]

Creation of this notebook was supported by IT Academy program of Information Technology Foundation for Education (HITSA).