The Mandelbrot map for Im(z) = 0 and Im(c) = 0, the real axis only

Cobweb diagram and iterated map

Clear[r]
iter = 500;(*500*)
x1=-1;x2=1;dx=0.003;
r1=-2;r2=1/4;dr=0.003;
od=Quiet[Rasterize[ListPlot[ParallelTable[Thread[{r,Quiet[Nest[#^2+r &,Range[x1,x2,dx],iter]]}],{r,r1,r2,dr}],
PlotStyle->{{Black,Opacity[0.08],AbsolutePointSize[0.001]},{Black,Opacity[0.08],AbsolutePointSize[0.001]}},
Frame->True,Axes->False,FrameLabel->{"r = Re(c)","z"},AspectRatio->0.5,PlotRange->{{-2,0.25},{-2,2}},ImageSize->630,LabelStyle->20]]]

Clear[r,n,k,x0]
Manipulate[
CobW=Show[Plot[{Nest[((#)^2)+r &, x,k],(x^2)+r,x},{x,-2,2},PlotStyle->{Blue,{Thickness[0.007],Red},Blue},Frame->True,PlotRange->{{-2,2},{-2,2}},AspectRatio->0.8,FrameLabel->{"(Subscript[z, n])","(Subscript[z, n+1])"},LabelStyle->20],Graphics[Flatten[MapIndexed[{Opacity[0.39],Line[{{#,If[#==x0,0,#]},{#,((#)^2)+r}}],Line[{{#,((#)^2)+r},{((#)^2)+r,((#)^2)+r}}]}& ,NestWhileList[((#)^2)+r&,x0,#1≠((#2)^2)+r&,2,n]]]],ImageSize->{320,320}];
IterP=ListLinePlot[NestList[((#)^2)+r&,x0,n],FrameLabel->{"n","(Subscript[z, n])"},PlotRange->{-2,2},Frame->True,Mesh->All,MeshStyle->{PointSize[Large],Red},PlotStyle->Gray,AspectRatio->0.8,ImageSize->{320,320},LabelStyle->20,DataRange->{0,n}];
LineP=Plot[3 Sign[ξ-r],{ξ,-2,0.6},ExclusionsStyle->Blue,PlotRange->{{-2,0.25},{-2,2}},Frame->True,Axes->False,FrameLabel->{"r = Re(c)","z"},AspectRatio->0.5,ImageSize->630,LabelStyle->20,Prolog->Inset[Image[od,ImageSize->630]]];
Grid[{{CobW,IterP},{LineP,SpanFromLeft}}],
{k,{1,2,3,4,5,6},ControlType->Setter},
{{n,50},0,150,1,ImageSize->Large,Appearance->"Labeled"}, 
{{r,-1.0},-2,1/4,ImageSize->Large,Appearance->"Labeled"},  
{{x0,0.0, "(Subscript[z, 0])"},-2,2,ImageSize->Large,Appearance->"Labeled"},SaveDefinitions->True]

Orbit diagram for real axis of the Mandelbrot set
Meaning of the set, the Mandelbrot set’s edge

iter = 500;(*500*)
x1=-1;x2=1;dx=0.003;
r1=-2;r2=1/4;dr=0.003;

impadding={{76,10},{76,10}};
od=Quiet[ListPlot[ParallelTable[Thread[{r,Quiet[Nest[#^2+r &,Range[x1,x2,dx],iter]]}],{r,r1,r2,dr}],
PlotStyle->{{Black,Opacity[0.08],AbsolutePointSize[0.001]},{Black,Opacity[0.08],AbsolutePointSize[0.001]}},
Frame->True,FrameLabel->{"r = Re(c)","z"},AspectRatio->0.9,PlotRange->{{-2,0.6},{-2,2}},ImagePadding->impadding,ImageSize->590,LabelStyle->20]];
line=Plot[0 x,{x,-2,0.6},PlotStyle->White];
Mp=MandelbrotSetPlot[MaxIterations->200,ColorFunction->"SunsetColors",FrameLabel->{"r, Re(c)","Im(c)"},ImagePadding->impadding,ImageSize->590,LabelStyle->20];
GraphicsGrid[{{od},{Show[Mp,line]}},Frame->All,Spacings->{0,0}]

Creation of this notebook was supported by IT Academy program of Information Technology Foundation for Education (HITSA).