Attractor reconstruction

Ex: Sine wave

Clear[t,d,tmax]
signal=Sin[t];
Plot[signal,{t,0,12 π},FrameLabel->{t,"f(t)"},Frame->True, LabelStyle->18,ImageSize->500]
Manipulate[
Column[{
Plot[Sin[t],{t,0,tmax},FrameLabel->{t,"f(t)"},Frame->True,AspectRatio->0.2, LabelStyle->18,ImageSize->500],
ParametricPlot[{signal,Sin[t+d]},{t,0,tmax},AxesLabel->{t,t+d},ImageSize->500,LabelStyle->18]}],
{{d,0.1,"Delay τ"},0,Pi,Appearance->"Labeled"},
{{tmax,1,"Time t"},1,2 Pi,Appearance->"Labeled"},
SaveDefinitions->True,TrackedSymbols:>{d,tmax}]

Ex: Quasiperiodic time-series

Clear[d,tmax]
signal=3 Sin[θ]+Sin[(Sqrt[2]) θ];(*quasiperiodic signal*)
Plot[signal,{θ,0,45 π},FrameLabel->{θ,"f(θ)"},Frame->True, LabelStyle->18,ImageSize->500]
Manipulate[Column[{
Plot[3 Sin[θ]+Sin[(Sqrt[2]) θ],{θ,0,tmax},FrameLabel->{θ,"f(θ)"},Frame->True,AspectRatio->0.2, LabelStyle->18,ImageSize->500],
ParametricPlot[{signal,3 Sin[θ+d]+Sin[(Sqrt[2]) (θ+d)]},{θ,0,tmax},AxesLabel->{θ,θ+d},ImageSize->500,LabelStyle->18]}],
{{d,1.4,"Delay τ"},0,11,Appearance->"Labeled"},
{{tmax,4,"Time/angle θ"},4,220,Appearance->"Labeled"},
SaveDefinitions->True,TrackedSymbols:>{d,tmax}]

Clear[t,d,tmax]
Manipulate[Column[{
Plot[3 Sin[θ]+Sin[(Sqrt[2]) θ],{θ,0,tmax},FrameLabel->{θ,"f(θ)"},Frame->True,AspectRatio->0.2, LabelStyle->18,ImageSize->500],
ParametricPlot3D[{3 Sin[θ]+Sin[(Sqrt[2]) θ],3 Sin[θ+d]+Sin[(Sqrt[2]) (θ+d)],3 Sin[θ+2 d]+Sin[(Sqrt[2]) (θ+2 d)]},{θ,0,tmax},AxesLabel->{θ,θ+d,θ+2 d},ImageSize->Large,LabelStyle->18]}],
{{d,4,"Delay τ"},0,11 ,Appearance->"Labeled"},
{{tmax,14,"Time/angle θ"},4,300,Appearance->"Labeled"},
SaveDefinitions->True,TrackedSymbols:>{d,tmax}]

Ex: The Lorenz attractor

Clear[t,d,tmax,tau,x,y,z]
Manipulate[
x0=6.1;y0=6;z0=10;d=10;r=28.24;b=8/3;
sol=NDSolve[{
x'[t]==d (y[t]-x[t]),
y'[t]==r x[t]-y[t]-x[t] z[t],
z'[t]==x[t] y[t]-b z[t],
x[0]==x0,y[0]==y0,z[0]==z0},{x,y,z},{t,0,tmax},MaxSteps->Infinity];
Column[{
Plot[Evaluate[y[t]/.sol],{t,0,tmax},ImageSize->530,LabelStyle->16,AxesLabel-> {t,y[t]},AspectRatio->0.2],
ParametricPlot3D[Evaluate[{y[t],y[t+tau], y[t+2 tau]}/.sol],{t,0,tmax},ImageSize->530,PlotPoints->100,LabelStyle->16,AxesLabel-> {y[t],y[t]+tau,y[t]+2 tau}]}],
{{tmax,60,"Time t"},5,100,ImageSize->Large,Appearance->"Labeled"},
{{tau,0.1,"Delay τ"},0,1.0,ImageSize->Large,Appearance->"Labeled"},
SaveDefinitions->True,TrackedSymbols:>{tmax,tau}]

Creation of this notebook was supported by IT Academy program of Information Technology Foundation for Education (HITSA).