The Rössler attractor

tmax=200;x0=0;y0=0;z0=0;
a=0.21;
b=0.15;
c=6;

diffx=-(y+z);
diffy=x+a y;
diffz=b+x z-c z;
soln=NDSolve[{
x'[t]==Evaluate[diffx/.{x->x[t],y->y[t],z->z[t]}],
y'[t]==Evaluate[diffy/.{x->x[t],y->y[t],z->z[t]}],
z'[t]==Evaluate[diffz/.{x->x[t],y->y[t],z->z[t]}],
x[0]==x0,y[0]==y0,z[0]==z0},{x,y,z},{t,0,tmax},MaxSteps->Infinity];
fixedpoints=Quiet[Solve[{diffx==0,diffy==0,diffz==0},{x,y,z}]];
Print[Style["Coordinates of fixed points",18,Blue]]
coordinates={x,y,z}/.fixedpoints
Gfp=Graphics3D[{PointSize[0.03],Red,Point[coordinates]}];
pplot=ParametricPlot3D[Evaluate[{x[t],y[t],z[t]}/.soln],{t,0,tmax},PlotPoints->1000,AxesLabel->{x[t],y[t],z[t]},PlotStyle->Thin,BoxRatios->{1,1,1},PlotRange->All,LabelStyle->20];
Show[pplot,Gfp]
Row[{Plot[Evaluate[x[t]/.soln],{t,0,tmax},AxesLabel-> {t,x[t]},PlotRange-> All,ImageSize->250,LabelStyle->20],
Plot[Evaluate[y[t]/.soln],{t,0,tmax},AxesLabel-> {t,y[t]},PlotRange-> All,ImageSize->250,LabelStyle->20],
Plot[Evaluate[z[t]/.soln],{t,0,tmax},AxesLabel-> {t,z[t]},PlotRange-> All,ImageSize->250,LabelStyle->20]}]

Coordinates of fixed points, analytically

Clear[a,b,c]
diffx=-(y+z);diffy=x+a y;diffz=b+x z-c z;
Solve[{diffx==0,diffy==0,diffz==0},{x,y,z}]

The Poincaré sections

maxt=2100;
a=0.21;
b=0.15;
c=6;
fpx=(1/2) (c-(Sqrt[-4 a b+(c^2)]));fpy=(1/2) (-(c/a)+((Sqrt[-4 a b+(c^2)])/a));fpz=((c-(Sqrt[-4 a b+(c^2)]))/(2 a));
YZdata=Block[{a0=a,b0=b,c0=c},
Reap[NDSolve[{
x'[t]==-(y[t]+z[t]),
y'[t]==x[t]+a y[t],
z'[t]==b+x[t] z[t]-c z[t],
x[0]==0,y[0]==0,z[0]==0,
WhenEvent[x[t]-fpx==0,Sow[{y[t]-fpy,z[t]-fpz}]]},{},{t,0,maxt},MaxSteps->∞]]][[-1,1]];
XZdata=Block[{a0=a,b0=b,c0=c},
Reap[NDSolve[{
x'[t]==-(y[t]+z[t]),
y'[t]==x[t]+a y[t],
z'[t]==b+x[t] z[t]-c z[t],
x[0]==0,y[0]==0,z[0]==0,
WhenEvent[y[t]-fpy==0,Sow[{x[t]-fpx,z[t]-fpz}]]},{},{t,0,maxt},MaxSteps->∞]]][[-1,1]];
ListPlot[YZdata,ImageSize->Large,PlotRange->All,PlotMarkers->{"•",5},FrameLabel->{y[t],z[t]},PlotLabel->Style["Poincaré section, yz-plane",Large],Frame->True,LabelStyle->20]
ListPlot[XZdata,ImageSize->Large,PlotRange->All,PlotMarkers->{"•",5},FrameLabel->{x[t],z[t]},PlotLabel->Style["Poincaré section, xz-plane",Large],Frame->True,LabelStyle->20]

Creation of this notebook was supported by IT Academy program of Information Technology Foundation for Education (HITSA).